TerraformでAWS Glue ジョブ 定期実行させてみた（EventBridge スケジュール vs Glue トリガー）

# EventBridge Schedulerの設定
resource "aws_scheduler_schedule" "eventbridge_schedule" {
  name       = "glue-job-invoke-scheduler" # スケジューラの名前を設定
  group_name = "default"                   # デフォルトのグループを使用

  # フレキシブルタイムウィンドウをOFFに設定
  flexible_time_window {
    mode = "OFF"
  }

  # スケジュール式の設定（例：毎日JST午前9時に実行）
  schedule_expression_timezone = "Asia/Tokyo"
  schedule_expression          = "cron(0 9 ? * * *)"

  # ターゲットの設定
  target {
    # この行が重要: Glueジョブを直接起動するためのAWS SDKアクションARN
    arn = "arn:aws:scheduler:::aws-sdk:glue:startJobRun"

    # EventBridge Schedulerが使用するIAMロールのARN
    role_arn = aws_iam_role.eventbridge_scheduler_role.arn

    # 起動するGlueジョブの設定
    input = jsonencode({
      JobName = "sample-glue-job" # 実行するGlueジョブの名前
    })
  }

  # スケジューラの状態を有効に設定
  state = "ENABLED"
}

# EventBridge Scheduler用のIAMロールを作成
resource "aws_iam_role" "eventbridge_scheduler_role" {
  name = "scheduled-glue-job-execution-role"

  # EventBridge Schedulerがこのロールを引き受けることを許可
  assume_role_policy = jsonencode({
    Version = "2012-10-17"
    Statement = [
      {
        Action = "sts:AssumeRole"
        Effect = "Allow"
        Principal = {
          Service = "scheduler.amazonaws.com"
        }
      }
    ]
  })
}

# AWSGlueServiceRoleポリシーをロールにアタッチ
resource "aws_iam_role_policy_attachment" "glue_service_role_attach" {
  role       = aws_iam_role.eventbridge_scheduler_role.name
  policy_arn = "arn:aws:iam::aws:policy/service-role/AWSGlueServiceRole"
}

resource "aws_glue_trigger" "example_trigger" {
  name              = "glue-job-invoke-trigger"   # Glueトリガーの名前を設定
  type              = "SCHEDULED"                 # Glueトリガーのタイプをスケジュールに設定
  schedule          = "cron(0 0 * * ? *)"         # 日本時間午前9時に毎日実行するためのCronスケジュール(UTC時間午前0時)
  start_on_creation = true                        # Glueトリガーを有効化

  actions {
    job_name = "sample-glue-job" # 実行するGlueジョブの名前を指定
  }
}